ActionScript入門Wiki

package
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.events.MouseEvent;
 
	public class Main extends Sprite
	{
		private const FLOOR:int = 0;				// 通路(部屋)
		private const WALL:int = 1;				// 壁
		private const WIDTH:int = 64;				// マップの横幅
		private const HEIGHT:int = 64;				// マップの縦幅
		private const ITERATIONS:int = 5;			// 生成を繰り返す回数
		private var fillProbability:Number = 0.4;		// 初期化時の壁と通路を入れる確率
		private var map:Array;					// マップ配列
		private var temp:Array;					// 生成される次の新しいマップ
		private var bd:BitmapData;				// BitmapData
 
		public function Main()
		{
			bd = new BitmapData(WIDTH, HEIGHT, false, 0x0);
			var bitmap:Bitmap = new Bitmap(bd);
			bitmap.scaleX = bitmap.scaleY = 7;
			addChild(bitmap);
 
			stage.addEventListener(MouseEvent.CLICK, onMouseClick);
			onMouseClick();
		}
 
		private function onMouseClick(event:MouseEvent = null):void
		{
			// マップを初期化
			initMap();
 
			// ITERATIONS回数だけマップ生成を繰り返す
			for (var i:int = 0; i < ITERATIONS; i++)
			{
				generateMap();
			}
 
			// マップ配列をもとにピクセルに色を入れて表示
			for (var y:int = 0; y < HEIGHT; y++)
			{
				for (var x:int = 0; x < WIDTH; x++)
				{
					if (map[y][x] == FLOOR) bd.setPixel(x, y, 0xFFFFFF);
					else bd.setPixel(x, y, 0x0);
				}
			}
		}
 
		private function initMap():void
		{
			map = [];
			temp = [];
 
			// 一定確率で壁または部屋(通路)を入れる
			for (var y:int = 0; y < HEIGHT; y++)
			{
				map[y] = [];
				for (var x:int = 0; x < WIDTH; x++)
				{
					map[y][x] = (Math.random() < fillProbability) ? WALL : FLOOR;
				}
			}
 
			// tempには壁を入れておく
			for (y = 0; y < HEIGHT; y++)
			{
				temp[y] = [];
				for (x = 0; x < WIDTH; x++)
				{
					temp[y][x] = WALL;
				}
			}
 
			// マップの周りに壁を敷き詰めておく
			for (y = 0; y < HEIGHT; y++)
			{
				map[y][0] = map[y][WIDTH - 1] = WALL;
			}
			for (x = 0; x < WIDTH; x++)
			{
				map[0][x] = map[HEIGHT -1][x] = WALL;
			}
		}
 
		private function generateMap():void
		{
			// 外側の壁以外を捜査する
			for (var y:int = 1; y < HEIGHT - 1; y++)
			{
				for (var x:int = 1; x < WIDTH - 1; x++)
				{
					var count3_3:int = 0;
					var count5_5:int = 0;
 
					// 現在走査しているタイルの周り3*3に、壁が幾つあるかをカウントする
					for (var yy:int = -1; yy <= 1; yy++)
					{
						for (var xx:int = -1; xx <= 1; xx++)
						{
							if (map[y + yy][x + xx] == WALL)
							{
								count3_3++;
							}
						}
					}
 
					// 現在走査しているタイルの周り5*5に、壁が幾つあるかをカウントする
					for (yy = y - 2; yy <= y + 2; yy++)
					{
						for (xx = x - 2; xx <= x + 2; xx++)
						{
							if (Math.abs(yy - y) == 2 && Math.abs(xx - x) == 2)
							{
								continue;
							}
							if (yy < 0 || xx < 0 || yy >= HEIGHT || xx >= WIDTH)
							{
								continue;
							}
							if (map[yy][xx] == WALL)
							{
								count5_5++;
							}
						}
					}
 
					//　3*3の範囲内で壁の数が5つ以上あった　または 5*5の範囲内で壁の数が2つ以下しかなかった
					// のどちらかの条件を満たしていれば、現在走査しているタイルに壁を入れる
					if (5 <= count3_3 || count5_5 <= 2)
					{
						temp[y][x] = WALL;
					}
					else
					{
						temp[y][x] = FLOOR;
					}
				}
			}
 
			// マップに値を移し反映させる
			for (y = 1; y < HEIGHT - 1; y++)
			{
				for (x = 1; x < WIDTH - 1; x++)
				{
					map[y][x] = temp[y][x];
				}
			}
		}
	}
}