ActionScript入門Wiki

package
{
	public class Player
	{
		private var _state:State;
		private var _hp:int;
		private var _maxHP:int;
		private var _name:String;
 
		public function Player()
		{
			_hp = 30;
			_maxHP = 30;
			_name = "主人公";
			_state = StateINN.instance;
		}
 
		public function getHPText():String
		{
			return "HP" + hp + "/" + maxHP;
		}
 
		public function get state():State 
		{
			return _state;
		}
 
		public function set state(value:State):void 
		{
			_state.exit(this);
			_state = value;
			_state.enter(this);
		}
 
		public function update():void
		{
			_state.update(this);
		}
 
		public function get hp():int 
		{
			return _hp;
		}
 
		public function set hp(value:int):void 
		{
			_hp = value;
			if (maxHP < _hp) _hp = maxHP;
			if (_hp < 0) _hp = 0;
		}
 
		public function get maxHP():int 
		{
			return _maxHP;
		}
 
		public function set maxHP(value:int):void 
		{
			_maxHP = value;
		}
 
		public function get name():String 
		{
			return _name;
		}
 
		public function set name(value:String):void 
		{
			_name = value;
		}
	}
}
 

package  
{
	public class StateDungeon implements State
	{	
		private static var _instance:StateDungeon;
		public function StateDungeon(lock:SingletonLock) {}
		public static function get instance():StateDungeon
		{
			if (_instance == null) _instance = new StateDungeon(new SingletonLock());
			return _instance;
		}
 
		public function enter(player:Player):void
		{
			trace(player.name + "はダンジョンに進入した");
		}
 
		public function update(player:Player):void
		{
			player.hp -= Math.random() * 5 + 1;
			trace(player.name　+ "はモンスターを倒した!! " + player.getHPText());
			if (player.hp == 0)
			{
				player.state = StateINN.instance;
			}
		}
 
		public function exit(player:Player):void
		{
			trace(player.name + "はダンジョンから脱出した");
		}
	}
}
 
class SingletonLock {}
 

package  
{
	public class StateINN implements State
	{	
		private static var _instance:StateINN;
		public function StateINN(lock:SingletonLock) {}
		public static function get instance():StateINN
		{
			if (_instance == null) _instance = new StateINN(new SingletonLock());
			return _instance;
		}
 
		public function enter(player:Player):void
		{
			trace(player.name + "は宿屋に入った");
		}
 
		public function update(player:Player):void
		{
			player.hp += 5;
			trace("ZZZ... : " + player.getHPText());
			if (player.hp == player.maxHP)
			{
				player.state = StateDungeon.instance;
			}
		}
 
		public function exit(player:Player):void
		{
			trace(player.name + "は宿屋から出た");
		}
	}
}
 
class SingletonLock {}